root/trunk/transformations/FacetsMLtoPyNN.xsl

<!-- must define a prefix for default namespace (fml) as soon as there is another prefix defined
otherwise XPath expressions don't treat default namespace -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fml="http://neuralensemble.org/FacetsML"
xmlns:class="http://neuralensemble.org/FacetsML/cellclass"
xmlns:rand="http://neuralensemble.org/FacetsML/randomNumberGenerator"
version="1.0">

<xsl:strip-space elements="*"/>
<xsl:output method="text" indent="no" omit-xml-declaration="yes"/>
<xsl:template match="/">
    
<xsl:text disable-output-escaping="yes">
import sys
from copy import copy

if hasattr(sys,"argv"):     # run using python
    if len(sys.argv) &lt; 2:
        print "Usage: python VAbenchmarks.py &lt;simulator> \n\n&lt;simulator> is either neuron, nest1, nest2 or pcsim"
        sys.exit(1)
    simulator = sys.argv[-2]
else:
    simulator = "oldneuron"    # run using nrngui -python
exec("from pyNN.%s import *" % simulator)
        
from pyNN.random import NumpyRNG, RandomDistribution
import pyNN.utility
</xsl:text>

<xsl:apply-templates/>

</xsl:template>

<xsl:template match="fml:network">

# === Build the network ========================================================

<xsl:if test="fml:extra">
extra = {<xsl:apply-templates select="fml:extra"/>}
</xsl:if>

node_id = setup(<xsl:apply-templates select="@*" mode="object"/><xsl:if test="fml:extra">**extra</xsl:if>)

if extra.has_key('threads'):
    print "%d Initialising the simulator with %d threads..." %(node_id, extra['threads'])
else:
    print "%d Initialising the simulator with single thread..." %(node_id)


print "%d Defining Random Number Generator object..." % node_id
<xsl:apply-templates select="fml:rng"/>

print "%d Defining cell types used..." % node_id
<xsl:apply-templates select="fml:cells"/>

print "%d Creating cell populations..." % node_id
<xsl:apply-templates select="fml:populations"/>

print "%d Connecting populations..." % node_id
<xsl:apply-templates select="fml:projections"/>

print "%d Setting weights..." % node_id
<xsl:apply-templates select="/fml:network/fml:projections/fml:projection[@weight]" mode="setWeights"/>


# === Setup recording ==========================================================
print "%d Setting up recording..." % node_id
<xsl:for-each select="//fml:population">
<xsl:variable name="name" select="@name"/>
<xsl:value-of select="$name"/>.record()
vrecord_list = [<xsl:value-of select="$name"/>[0],<xsl:value-of select="$name"/>[1]]
<xsl:value-of select="$name"/>.record_v(vrecord_list)
</xsl:for-each>

buildCPUTime = Timer.elapsedTime()

# === Run simulation ===========================================================
print "%d Running simulation..." % node_id
Timer.reset()
<xsl:variable name="tstop" select="/fml:network/@sim_duration"/>
run(<xsl:value-of select="$tstop"/>)

simCPUTime = Timer.elapsedTime()

<xsl:for-each select="//fml:population">
<xsl:variable name="name" select="@name"/>
<xsl:value-of select="$name"/>_rate = <xsl:value-of select="$name"/>.meanSpikeCount()*1000./<xsl:value-of select="$tstop"/><xsl:text>
</xsl:text>
</xsl:for-each>


# === Print results to file ====================================================

print "%d Writing data to file..." % node_id
Timer.reset()
<xsl:for-each select="//fml:population">
<xsl:variable name="name" select="@name"/>
<xsl:value-of select="$name"/>.printSpikes("<xsl:value-of select="$name"/>.ras")
<xsl:value-of select="$name"/>.print_v("<xsl:value-of select="$name"/>.v")
</xsl:for-each>
writeCPUTime = Timer.elapsedTime()
</xsl:template>





<!-- 
<extra name="threads" value="2"/>    ->        extra = {'threads' : 2}
-->
<xsl:template match="fml:extra"><xsl:call-template name="dumpDictParam"/>
</xsl:template>


<!--
<rng name="rng" seed="98765" generator="NumPYRNG"/>     ->      rng = NumPYRNG(98765+node_id)
-->
<xsl:template match="fml:rng">
rng = <xsl:value-of select="@generator"/>(<xsl:value-of select="@seed"/>+node_id)
</xsl:template>


<!--
<cells>
   <cell name="cellA">
       <class:IF_cond_exp tau_m="20." tau_syn_E="5." tau_syn_I="10."
                        v_rest="-60." v_reset="-60." v_thresh="-50."
                        cm="1." tau_refrac="5." e_rev_E="0."
                        e_rev_I="-80."/>
   </cell>
</cells>

             ->

cellclass['cellA'] = IF_cond_exp
cellparams['cellA'] = { 'tau_m': 20., 'tau_syn_E': 5., 'tau_syn_I': 10., 'v_rest': -60., 'v_reset': -60., 'v_thresh': -50., 'cm': 1., 'tau_refrac': 5., 'e_rev_E': 0., 'e_rev_I': -80., }
-->
<xsl:template match="fml:cells">
cellclass = {}
cellparams = {}
<xsl:apply-templates/>
</xsl:template>


<!--
<populations>
    <population name="exc_cells" label="Excitatory_Cells">
        <dim size="4000"/>
        <cell_type name="cellA"/>
        <randomInit rng="rng">
            <rand:uniform min="-60." max="-50."/>
        </randomInit>
    </population>
</populations>

             ->

exc_cells = Population((4000,), cellclass = cellclass['cellA'], cellparams = cellparams['cellA'], label="Excitatory_Cells", )
exc_cells.randomInit(RandomDistribution('uniform',[-60., -50., ], rng=rng))
-->
<xsl:template match="fml:populations">
<xsl:apply-templates/>
</xsl:template>


<!--
<projections>
    <projection name="e2e"
                presynaptic_population_name="exc_cells"
                postsynaptic_population_name="exc_cells"
                method="fixedProbability"
                weight="0.004"
                target="excitatory"
                rng="rng">
        <methodParameter name="p_connect" value="0.02"/>
    </projection>
</projections>

             ->

e2e = Projection(exc_cells, exc_cells, method="fixedProbability", methodParameters=0.02, target="excitatory", rng=rng, )
-->
<xsl:template match="fml:projections">
<xsl:apply-templates/>
</xsl:template>


<!--
                weight="0.004"        ->        e2e.setWeights(0.004)
-->
<xsl:template match="fml:projection" mode="setWeights">
<xsl:value-of select="@name"/>.setWeights(<xsl:value-of select="@weight"/>)
</xsl:template>




<!--
cell type definition
-->
<xsl:template match="fml:cell">
cellclass['<xsl:value-of select="@name"/>'] = <xsl:apply-templates select="class:*">
<xsl:with-param name="celltypeid" select="@name"/>
</xsl:apply-templates>
</xsl:template>

<xsl:template match="class:*"><xsl:param name="celltypeid"/><xsl:value-of select="local-name(current())"/>
<xsl:if test="attribute::node()">
cellparams['<xsl:value-of select="$celltypeid"/>'] = { <xsl:call-template name="dumpCellparams"/>}
</xsl:if>
</xsl:template>

<xsl:template match="class:NonStandardCellType"><xsl:param name="celltypeid"/>"<xsl:value-of select="@name"/>"
cellparams['<xsl:value-of select="$celltypeid"/>'] = { <xsl:apply-templates select="class:cellparams"/> }
</xsl:template>

<xsl:template match="class:cellparams"><xsl:call-template name="dumpDictParam"/>
</xsl:template>


<!--
population definition
-->
<xsl:template match="fml:population">
<xsl:value-of select="@name"/> = Population((<xsl:apply-templates select="fml:dim"/>), <xsl:apply-templates select="fml:cell_type"/><xsl:apply-templates select="@label"/>)
<xsl:apply-templates select="fml:randomInit">
<xsl:with-param name="populationid" select="@name"/>
</xsl:apply-templates>
</xsl:template>

<xsl:template match="fml:dim"><xsl:value-of select="@size"/>,</xsl:template>

<xsl:template match="fml:cell_type">cellclass = cellclass['<xsl:value-of select="@name"/>'], cellparams = cellparams['<xsl:value-of select="@name"/>'], </xsl:template>

<xsl:template match="fml:randomInit">
<xsl:param name="populationid"/>

<xsl:value-of select="$populationid"/>.randomInit(<xsl:apply-templates select="rand:*">
<xsl:with-param name="rng" select="@rng"/>
</xsl:apply-templates>)

</xsl:template>


<xsl:template match="rand:*">
<xsl:param name="rng"/>RandomDistribution('<xsl:value-of select="local-name(current())"/>',[<xsl:apply-templates select="@*" mode="value"/>], rng=rng)</xsl:template>


<!--
projection definition
-->
<xsl:template match="fml:projection"><xsl:value-of select="@name"/> = Projection(<xsl:value-of select="@presynaptic_population_name"/>, <xsl:value-of select="@postsynaptic_population_name"/>, <xsl:apply-templates select="@method"/><xsl:apply-templates select="fml:methodParameter"/><xsl:apply-templates select="@source|@target|@label"/><xsl:apply-templates select="@rng" mode="object"/>)
</xsl:template>

<xsl:template match="fml:methodParameter">methodParameters=<xsl:choose>
<xsl:when test="count(current())=1"><xsl:value-of select="@value"/>
</xsl:when>
<xsl:otherwise>
{<xsl:call-template name="dumpDictParam"/>}
</xsl:otherwise>
</xsl:choose>, </xsl:template>


<!-- 
functions to dump attributes as label="aLabel" or label=aLabel or just aLabel
-->
<xsl:template match="@*"><xsl:value-of select="local-name()"/>="<xsl:value-of select="current()"/>", </xsl:template>

<xsl:template match="@*" mode="object"><xsl:value-of select="local-name()"/>=<xsl:value-of select="current()"/>, </xsl:template>

<xsl:template match="@*" mode="value"><xsl:value-of select="current()"/>, </xsl:template>


<!--
dump generic parameters as : <methodParameter name="p_connect" value="0.005"/>
-->
<xsl:template name="dumpDictParam">'<xsl:value-of select="@name"/>': <xsl:value-of select="@value"/>, </xsl:template>

<!--
generically dump attributes as a dict :
<class:IF_cond_exp tau_m="20." tau_syn_E="5." tau_syn_I="10."
                                v_rest="-60." v_reset="-60." v_thresh="-50."
                                cm="1." tau_refrac="5." e_rev_E="0."
                                e_rev_I="-80."/>

             ->

'tau_m': 20., 'tau_syn_E': 5., 'tau_syn_I': 10., 'v_rest': -60., 'v_reset': -60., 'v_thresh': -50., 'cm': 1., 'tau_refrac': 5., 'e_rev_E': 0., 'e_rev_I': -80.,
-->
<xsl:template name="dumpCellparams"><xsl:for-each select="attribute::*">'<xsl:value-of select="local-name()"/>': <xsl:value-of select="current()"/>, </xsl:for-each>
</xsl:template>


</xsl:stylesheet>