root/trunk/transformations/FacetsMLtoNeuroML.xsl

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:fml="http://neuralensemble.org/FacetsML"
    xmlns:class="http://neuralensemble.org/FacetsML/cellclass"
    xmlns:rand="http://neuralensemble.org/FacetsML/randomNumberGenerator"
    xmlns:net="http://morphml.org/networkml/schema"
    xmlns:mml="http://morphml.org/morphml/schema"
    xmlns:cml="http://morphml.org/channelml/schema"
    xmlns:meta="http://morphml.org/metadata/schema"
    xmlns:bio="http://morphml.org/biophysics/schema"
    xmlns="http://morphml.org/neuroml/schema">
    <xsl:output method="xml" indent="yes" xml:space="default"/>
    <xsl:template match="/">
            <xsl:apply-templates select="fml:network"/>
    </xsl:template>
    
    <xsl:template match="fml:network">
        <neuroml xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
            xsi:schemaLocation="http://morphml.org/neuroml/schema Level3/NeuroML_Level3_v1.6.xsd"
            xmlns:net="http://morphml.org/networkml/schema"
            xmlns:mml="http://morphml.org/morphml/schema"
            xmlns:cml="http://morphml.org/channelml/schema"
            xmlns:meta="http://morphml.org/metadata/schema"
            xmlns:bio="http://morphml.org/biophysics/schema"
            xmlns="http://morphml.org/neuroml/schema"
            lengthUnits="micron">
        <xsl:apply-templates select="fml:cells"/>
        <channels units="Physiological Units">
            <cml:ion charge="1" name="non_specific" default_erev="-65.0"/>
            <xsl:apply-templates select="//fml:cell" mode="addChannelMechanisms"/>
        </channels>
        <xsl:apply-templates select="fml:populations"/>
        <xsl:apply-templates select="fml:projections"/>
        </neuroml>
    </xsl:template>
    
    
    <xsl:template match="fml:cells">
        <cells>
            <xsl:apply-templates select="fml:cell"/>
        </cells>
    </xsl:template>    
    
    <xsl:template match="fml:cell">
        <cell name="{@name}">
            <xsl:apply-templates select="class:IF_cond_exp">
                <xsl:with-param name="name" select="@name"/>
            </xsl:apply-templates>
        </cell>
    </xsl:template>
    
    <xsl:template match="fml:cell" mode="addChannelMechanisms">
            <xsl:apply-templates select="class:IF_cond_exp" mode="addChannelMechanisms">
                <xsl:with-param name="name" select="@name"/>
            </xsl:apply-templates>
    </xsl:template>
    
    
    <xsl:template match="class:IF_cond_exp">
        <xsl:param name="name"/>
        <meta:notes>Instance of PyNN IF_cond_exp cell type</meta:notes>
        <mml:segments>
            <mml:segment id="0" cable="0" name="Soma">
                <mml:proximal y="0" x="0" z="0" diameter="318.309886184"/>
                <mml:distal y="0" x="0" z="100" diameter="318.309886184"/>
            </mml:segment>
        </mml:segments>
        <mml:cables>
            <mml:cable id="0" name="Soma">
                <meta:group>all</meta:group>
            </mml:cable>
        </mml:cables>
        <biophysics units="Physiological Units">
            <bio:mechanism type="Channel Mechanism" name="IandF_{$name}"/>
            <bio:mechanism type="Channel Mechanism" name="pas_{$name}">
                <bio:parameter name="gmax" value="5e-05">
                    <bio:group>all</bio:group>
                </bio:parameter>
            </bio:mechanism>
            <bio:specificCapacitance>
                <bio:parameter value="{@cm}">
                    <bio:group>all</bio:group>
                </bio:parameter>
            </bio:specificCapacitance>
            <bio:specificAxialResistance>
                <bio:parameter value="0.1">
                    <bio:group>all</bio:group>
                </bio:parameter>
            </bio:specificAxialResistance>
            <bio:initialMembPotential>
                <bio:parameter value="{@v_init}">
                    <bio:group>all</bio:group>
                </bio:parameter>
            </bio:initialMembPotential>
            <net:potentialSynapticLocation>
                <net:synapse_type>ExcitatorySynapse_<xsl:value-of select="$name"/></net:synapse_type>
                <net:synapse_direction>preAndOrPost</net:synapse_direction>
                <net:group>all</net:group>
            </net:potentialSynapticLocation>
            <net:potentialSynapticLocation>
                <net:synapse_type>InhibitorySynapse_<xsl:value-of select="$name"/></net:synapse_type>
                <net:synapse_direction>preAndOrPost</net:synapse_direction>
                <net:group>all</net:group>
            </net:potentialSynapticLocation>
        </biophysics>
    </xsl:template>
    
    <xsl:template match="class:IF_cond_exp" mode="addChannelMechanisms">
        <xsl:param name="name"/>
        <cml:channel_type name="pas_{$name}" density="yes">
            <meta:notes>Simple example of a leak/passive conductance</meta:notes>
            <cml:current_voltage_relation>
                <cml:ohmic ion="non_specific">
                    <cml:conductance default_gmax="5e-05"/>
                </cml:ohmic>
            </cml:current_voltage_relation>
        </cml:channel_type>
        <cml:channel_type name="IandF_{$name}">
            <meta:notes>Spike and reset mechanism</meta:notes>
            <cml:current_voltage_relation>
                <cml:integrate_and_fire threshold="{@v_thresh}" g_refrac="0.1" t_refrac="{@tau_refrac}" v_reset="{@v_reset}"/>
            </cml:current_voltage_relation>
        </cml:channel_type>
        <cml:synapse_type name="ExcitatorySynapse_{$name}">
            <cml:doub_exp_syn rise_time="{@tau_syn_E}" max_conductance="1.0e-5" reversal_potential="{@e_rev_E}" decay_time="5.0"/>
        </cml:synapse_type>
        <cml:synapse_type name="InhibitorySynapse_{$name}">
            <cml:doub_exp_syn rise_time="{@tau_syn_I}" max_conductance="1.0e-5" reversal_potential="{@e_rev_I}" decay_time="5.0"/>
        </cml:synapse_type>
    </xsl:template>
    
    <xsl:template match="fml:populations">
        <net:populations>
            <xsl:apply-templates select="fml:population"/>
        </net:populations>
    </xsl:template>
    
    <xsl:template match="fml:population">
        <net:population name="{@name}">
            <xsl:variable name="size" select="fml:dim/@size"/>
            <net:cell_type><xsl:value-of select="fml:cell_type/@name"/></net:cell_type>
            <net:pop_location>
                <net:random_arrangement>
                    <net:population_size><xsl:value-of select="$size"/></net:population_size>
                    <net:rectangular_location>
                        <meta:corner x="0" y="0" z="0"/>
                        <meta:size depth="{$size}" height="{$size}" width="{$size}"/>
                    </net:rectangular_location>
                </net:random_arrangement>
            </net:pop_location>
        </net:population>
    </xsl:template>
    
    <xsl:template match="fml:projections">
        <net:projections units='Physiological Units'>
            <xsl:apply-templates select="fml:projection"/>
        </net:projections>
    </xsl:template>
    
    <xsl:template match="fml:projection">
        <net:projection name="{@name}">
            <net:source><xsl:value-of select="@presynaptic_population_name"/></net:source>
            <net:target><xsl:value-of select="@postsynaptic_population_name"/></net:target>
            <net:synapse_props>
                <net:synapse_type>
                    <!-- here I try to detect if the synapse to use is excitatory or inhibitory and if it is the synapse type of the source population
                    or the synapse type of the target population -->
                    <xsl:choose>
                        <!-- if target attribute is specified -->
                        <xsl:when test="@target">
                            <xsl:choose>
                                <xsl:when test="contains(@target,'xcitatory')">
                                    ExcitatorySynapse_<xsl:value-of select="@postsynaptic_population_name"/>
                                </xsl:when>
                                <xsl:when test="contains(@target,'nhibitory')">
                                    InhibitorySynapse_<xsl:value-of select="@postsynaptic_population_name"/>
                                </xsl:when>
                                <!-- default value is ExcitatorySynapse_ -->
                                <xsl:otherwise>
                                    ExcitatorySynapse_<xsl:value-of select="@postsynaptic_population_name"/>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:choose>
                                <!-- if source attribute is specified -->
                                <xsl:when test="@source">
                                    <xsl:choose>
                                        <xsl:when test="contains(@target,'xcitatory')">
                                            ExcitatorySynapse_<xsl:value-of select="@presynaptic_population_name"/>
                                        </xsl:when>
                                        <xsl:when test="contains(@target,'nhibitory')">
                                            InhibitorySynapse_<xsl:value-of select="@presynaptic_population_name"/>
                                        </xsl:when>
                                        <!-- default value is ExcitatorySynapse_ -->
                                        <xsl:otherwise>
                                            ExcitatorySynapse_<xsl:value-of select="@presynaptic_population_name"/>
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:when>
                                <xsl:otherwise>
                                    <!-- default value is ExcitatorySynapse_ of the postsynaptic population -->
                                    ExcitatorySynapse_<xsl:value-of select="@postsynaptic_population_name"/>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:otherwise>
                    </xsl:choose>
                </net:synapse_type>
                <net:default_values weight="{@weight}"/>
            </net:synapse_props>
            <net:connectivity_pattern>
                <xsl:apply-templates select="@method"/>
            </net:connectivity_pattern>
        </net:projection>
    </xsl:template>
    
    <xsl:template match="@method">
        <xsl:choose>
            <xsl:when test="current()='fixedProbability'">
                <xsl:variable name="p_connect" select="../fml:methodParameter[@name='p_connect']/@value"/>
                <net:fixed_probability probability='{$p_connect}'/>
            </xsl:when>
            <xsl:when test="current()='per_cell_connection'">
                <xsl:variable name="n" select="../fml:methodParameter[@name='n']/@value"/>
                <net:per_cell_connection num_per_source="{$n}"/>
            </xsl:when>
            <xsl:otherwise>
                <net:all_to_all/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    
</xsl:stylesheet>